也许，取决于所需的边缘质量：

img = Import@"http://i.stack.imgur.com/k7E1F.png";
mask = ChanVeseBinarize[img, TargetColor -> {1., 1., 1.}, "LengthPenalty" -> 10]
mask1 = Blur[Erosion[ColorNegate[mask], 2], 5]
Rasterize[SetAlphaChannel[img, mask1], Background -> None]

编辑

Stealing a bit from @Szabolcs

img2 = Import@"http://i.stack.imgur.com/k7E1F.png";
(*key point:scale up image to smooth the edges*)
img = ImageResize[img2, 4 ImageDimensions[img2]];
mask = ChanVeseBinarize[img, TargetColor -> {1., 1., 1.}, "LengthPenalty" -> 10];
mask1 = Blur[Erosion[ColorNegate[mask], 8], 10];
f[col_] := Rasterize[SetAlphaChannel[img, mask1], Background -> col, 
                     ImageSize -> ImageDimensions@img2]
GraphicsGrid[{{f@Red, f@Blue, f@Green}}]

点击放大

编辑2

只是为了了解图像中光环和背景缺陷的程度：

img = Import@"http://i.stack.imgur.com/k7E1F.png";
Join[{img}, MapThread[Binarize, {ColorSeparate[img, "HSB"], {.01, .01, .99}}]]

ColorNegate@ImageAdd[EntropyFilter[img, 1] // ImageAdjust, ColorNegate@img]

只需将任何“几乎接近白色”的像素替换为具有相同RGB颜色和透明通道上的Sigmoid渐变的像素即可。您可以应用从实体到透明的线性过渡，但是正弦波或Sigmoid或Tanh看起来更自然，具体取决于您要寻找的边缘的锐度，它们会迅速从介质移到实体或透明，但不是逐步/二进制方式，这就是您现在所拥有的。

这样想：

假设R，G，B分别为0.0-1.0，那么我们将白色表示为单个数字，因为R + G + B = 1.0 * 3 = 3.0。

取出每种颜色的一点点会使它有点“灰白色”，但是全部使用3种颜色的点子会使它比不使用任何一种颜色的点多得多。假设您允许在任何一个通道上减少10％：1.0 * .10 = .1，现在将这种损失分布在所有三个通道上，并将其限制在alpha通道的0和1之间（如果小于.1，则（损失= 0.9）=> 0和（损失= 1.0）=> 1：

threshold=.10;
maxLoss=1.0*threshold;
loss=3.0-(R+G+B);
alpha=If[loss>maxLoss,0,loss/maxLoss];
(* linear scaling is used above *)
(* or use 1/(1 + Exp[-10(loss - 0.5maxLoss)/maxLoss]) to set sigmoid alpha *)
(* Log decay: Log[maxLoss]/Log[loss]
      (for loss and maxLoss <1, when using RGB 0-255, divide by 255 to use this one *)

setNewPixel[R,G,B,alpha];

以供参考：

maxLoss = .1;
Plot[{ 1/(1 + Exp[-10(loss - 0.5maxLoss)/maxLoss]),
       Log[maxLoss]/Log[loss],
       loss/maxLoss
     }, {loss, 0, maxLoss}]

您所面临的唯一危险（或好处？）是，这并不关心实际上是照片一部分的白色。它删除所有白人。这样一来，如果您拥有白色汽车的图片，则最终会出现透明的斑点。但是从您的示例来看，这似乎是理想的效果。

只是作为一个初学者玩-令人惊讶的是有多少个工具可用。

b = ColorNegate[
    GaussianFilter[MorphologicalBinarize[i, {0.96, 0.999}], 6]];
c = SetAlphaChannel[i, b];
Show[Graphics[Rectangle[], Background -> Orange, 
     PlotRangePadding -> None], c]

此功能实现了马克·兰瑟姆（Mark Ransom）描述的反向混合，这是一个小的但明显的改进：

reverseBlend[img_Image, alpha_Image, bgcolor_] :=
 With[
  {c = ImageData[img], 
   a = ImageData[alpha] + 0.0001, (* this is to minimize ComplexInfinitys and considerably improve performance *)
   bc = bgcolor},

  ImageClip@
   Image[Quiet[(c - bc (1 - a))/a, {Power::infy, 
       Infinity::indet}] /. {ComplexInfinity -> 0, Indeterminate -> 0}]
  ]

这是背景去除功能。 threshold参数用于图像的初始二值化， minSizeCorrection用于调整二值化后要删除的小型垃圾组件的大小限制。

removeWhiteBackground[img_, threshold_: 0.05, minSizeCorrection_: 1] :=
  Module[
  {dim, bigmask, mask, edgemask, alpha},
  dim = ImageDimensions[img];
  bigmask = 
   DeleteSmallComponents[
    ColorNegate@
     MorphologicalBinarize[ColorNegate@ImageResize[img, 4 dim], threshold], 
    Round[minSizeCorrection Times @@ dim/5]];
  mask = ColorNegate@
    ImageResize[ColorConvert[bigmask, "GrayScale"], dim];
  edgemask = 
   ImageResize[
    ImageAdjust@DistanceTransform@Dilation[EdgeDetect[bigmask, 2], 6],
     dim];
  alpha = 
   ImageAdd[
    ImageSubtract[
     ImageMultiply[ColorNegate@ColorConvert[img, "GrayScale"], 
      edgemask], ImageMultiply[mask, edgemask]], mask];
  SetAlphaChannel[reverseBlend[img, alpha, 1], alpha]
  ]

测试功能：

img = Import["http://i.stack.imgur.com/k7E1F.png"];

background = 
  ImageCrop[
   Import["http://cdn.zmescience.com/wp-content/uploads/2011/06/\
forest2.jpg"], ImageDimensions[img]];

result = removeWhiteBackground[img]

ImageCompose[background, result]
Rasterize[result, Background -> Red]
Rasterize[result, Background -> Black]

简要说明其工作原理：

1. 选择您喜欢的可产生相对精确的锐边的二值化方法

2. 将其应用于放大的图像，然后将获得的mask缩小到原始大小。这使我们抗锯齿。大部分工作已经完成。

3. 为了进行较小的改进，请使用负片的亮度作为Alpha将图像混合到背景上，然后在边缘周围的薄区域（ edgemask ）中将获得的图像混合在原始图像上，以减少边缘上白色像素的可见度。计算与这些操作相对应的Alpha通道（有点神秘的ImageMultiply/Add表达式）。

4. 现在我们有了一个Alpha通道的估计值，因此我们可以进行反向混合。

第3步和第4步的改进并不多，但区别显而易见。

您可以采取的可能步骤：

• 扩张面膜
• 模糊它
• 使用遮罩，根据与白色的距离设置透明度
• 使用遮罩，调整饱和度，使以前更白的颜色更饱和。

我对图像处理完全陌生，但是在使用版本8的新形态图像处理功能后，这是我得到的：

mask = DeleteSmallComponents[
   ColorNegate@
    Image[MorphologicalComponents[ColorNegate@img, .062, 
      Method -> "Convex"], "Bit"], 10000];
Show[Graphics[Rectangle[], Background -> Red, 
  PlotRangePadding -> None], SetAlphaChannel[img, ColorNegate@mask]]

在belisarius的遮罩生成的一些帮助下，这是尝试实现Mark Ransom的方法的尝试：

找到对象的边界：

img1 = SetAlphaChannel[img, 1];
erosionamount=2;
mb = ColorNegate@ChanVeseBinarize[img, TargetColor -> {1., 1., 1}, 
      "LengthPenalty" -> 10];
edge = ImageSubtract[Dilation[mb, 2], Erosion[mb, erosionamount]];

ImageApply[{1, 0, 0} &, img, Masking ->edge]

设置Alpha值：

edgealpha = ImageMultiply[ImageFilter[(1 - Mean[Flatten[#]]^5) &, 
   ColorConvert[img, "GrayScale"], 2, Masking -> edge], edge];
imagealpha = ImageAdd[edgealpha, Erosion[mb, erosionamount]];
img2 = SetAlphaChannel[img, imagealpha];

反向混色：

img3 = ImageApply[Module[{c, \[Alpha], bc, fc},
   bc = {1, 1, 1};
   c = {#[[1]], #[[2]], #[[3]]};
   \[Alpha] = #[[4]];
   If[\[Alpha] > 0, Flatten[{(c - bc (1 - \[Alpha]))/\[Alpha], \[Alpha]}], {0., 0., 
   0., 0}]] &, img2];

Show[img3, Background -> Pink]

请注意，有些边缘有白色绒毛吗？将其与第一张图像中的红色轮廓进行比较。我们需要一个更好的边缘检测器。增加腐蚀量有助于起毛，但其他面变得太透明，因此需要权衡边缘蒙版的宽度。不过，考虑到本身没有模糊操作，这非常好。

在各种图像上运行该算法以测试其鲁棒性，以查看其自动化程度，将是有益的。

我将一般性地讲，而不是专门针对Mathematica。我不知道这些操作是困难的还是琐碎的。

第一步是估计图像边缘上像素的alpha（透明度）级别。现在，您使用的是严格的阈值，因此Alpha值是0％完全透明或100％完全不透明。您应该在背景的总白色和毫无疑问地是图像的一部分的颜色之间定义一个范围，并设置适当的比例-如果颜色与背景更接近，则其alpha值较低，如果颜色与较暗的截止点更接近，则该比例为高alpha。之后，您可以根据周围的Alpha值进行调整-透明度包围的像素越多，像素本身就越可能变得透明。

一旦有了alpha值，就需要进行反向混合以获得正确的颜色。当图像显示在背景上时，它使用公式c = bc*(1-a)+fc*a根据alpha值进行混合，其中bc是背景色， fc是前景色。在您的情况下，背景为白色（255,255,255），前景色为未知色，因此我们将公式反向： fc = (c - bc*(1-a))/a 。当a=0 ，公式要求除以零，但是颜色无论如何都没有关系，因此只需使用黑色或白色即可。

我建议为此使用Photoshop并将其另存为PNG。